// state management and back/forward browser button functionality
// v 0.8
// 2005-08-20
// leo@blixtsystems.com
// Part of statemanagement system for flash
// Full package available at:
// http://www.blixtsystems.com/index.html?page=downloads&pid=7&ss=pid
// Licensed under GNU GPL, see license.txt included with package for details

// create object to hold the state information
_global.state_obj = new Object();

if(queryStr && queryStr != "undefined"){
	state_obj= str2Object(queryStr);
}

// check that the page specified exists
//getURL("javascript:loadPage('"+page+"');");
var valid=false;
for (var i in page_array) {
	if (page == page_array[i]) {
		valid = true;
	}
}
// if the request is not for a valid page goto first page
if (!valid) {
	page = page_array[0];
	state_obj.page = page;
}
// function called when pressing a nav button
_global.gotoPage = function(p) {
	// update the page var
	page = p;
	// update state object
	state_obj=new Object();
	state_obj.page = p;
	pollCount=0;
	updateState();
	oldpage=p;
	// go to the page
	goState("page");
	//_root.gotoAndStop(p);
};
var c = 0;
function checkPage() {
	var a:Array=stateVars_array;
	var i:Number;
	// check if the state vars updated and if so call the goState function defining how to handle updates
	for(i=0;i<a.length;i++){
		if(_root["old"+a[i]] != _root[a[i]] || (oldss != ss && ss==a[i])){
			pollCount = 0;
			goState(a[i]);
		}
		_root["old"+a[i]]=_root[a[i]];
	}
	if (_root.isMSIE == "false") {
		// hack using a count var to set a delay for non-IE browsers before checking the state in the address bar
		pollCount++;
		// checking every 15th frame, low values puts strain on the browser, high values a slow response
		if (pollCount == 15) {
			// call javascript to get state from browser and send it back to flash
			getURL("javascript:getState();");
			pollCount = 0;
		}
	}
}
function updateState() {
	var params:String=obj2String(state_obj);
   //getURL("javascript:alert('"+params+"');");
	// with IE we use the VBscript function to update addressbar
	if (_root.isMSIE == "true") {
	//	fscommand("putTitle", siteName+" "+state_obj.page);
		fscommand("putHREF", "#"+params);
		fscommand("loadPage", params);
		fscommand("putHistTitle", siteName+" "+state_obj.page);
	} else {
		// with non IE we use javascript
		// reset the polling count
		c = 0;
		// send state vars and title
		getURL("javascript:putHref('"+params+"','"+state_obj.page+"');");
	}
}
setStateVar= function(vari:String, val:String, noUpdate:Boolean):Void {
	state_obj=new Object();
	state_obj.page=page;
	// update object
	state_obj[vari] = val;
	state_obj.ss=vari;
	ss=vari;
	oldss=vari;
	_root[vari]=val;
	_root["old"+vari]=val;
	pollCount = 0;
	// send updated state vars
	if(!noUpdate){
		updateState();
	}
}
function str2Object(str:String):Object{
	var o:Object=new Object();
	var i, values;
	var chunk = str.split("&");
	for (i in chunk) {
		values = chunk[i].split("=");
		o[values[0]] = values[1];
	}
	return o;
}
function obj2String(o:Object):String{
	var str:String="";
	// build string with the state variables
	for (var prop in o) {
		str += prop+"="+o[prop]+"&";
	}
	str = substring(str, 0, str.length-1);
	return str;
}